Simulación de Circuitos – Pspice II

En la siguiente figura se observa el circuito transformado mediante la utilización del modelo del amplificador operacional.

El fichero fuente para la descripción del circuito es el siguiente:

CIRCUITO CON AMPLIFICADORES OPERACIONALES

V1 1 0 sin(1m .5 1.591e5 0 0 90)

R1 1 2 100

R2 2 4 100k

R3 3 0 1k

R4 4 5 1k

R5 6 0 2.2k

R6 7 6 2.2k

** Descripción de los AMPO mediante subcircuitos.

.SUBCKT AMPO 1 2 3 4

Ri1 1 2 1e10

E1 3 4 2 1 1e6

.ENDS AMPO

** Inclusión de los amplificadores operacionales en el circuito global

X1 2 3 4 0 AMPO

X2 5 6 7 0 AMPO

.TF V(7) V1

.SENS V(7)

.TRAN 1e-6 1e-4

.PROBE

.END

El fichero de salida del circuito es el siguiente:

** SMALL SIGNAL BIAS SOLUTION

** TEMPERATURE = 27.000 DEG C

********************************************************

VOLTAGE SOURCE CURRENTS

NAME CURRENT

V1 -9.990E-06

TOTAL POWER DISSIPATION 9.99E-09 WATTS

**** SMALL-SIGNAL CHARACTERISTICS

V(7)/V1 = -1.998E+03

INPUT RESISTANCE AT V1 = 1.001E+02

OUTPUT RESISTANCE AT V(7) = 0.000E+00

**** DC SENSITIVITY ANALYSIS TEMPERATURE = 27.000 DEG C

******************************************************************************

DC SENSITIVITIES OF OUTPUT V(7)

CIRCUITO CON AMPLIFICADORES OPERACIONALES

**** INITIAL TRANSIENT SOLUTION TEMPERATURE = 27.000 DEG C

******************************************************************************

NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

( 1) .5010 ( 2) 500.5E-06 ( 3) 50.05E-12 ( 4) -500.5000

( 5) -500.5000 ( 6) -500.5000 ( 7)-1001.0000

VOLTAGE SOURCE CURRENTS

NAME CURRENT

V1 -5.005E-03

TOTAL POWER DISSIPATION 2.51E-03 WATTS

En la siguiente gráfica se puede observar la señal sinusoidal, como se puede observar es una señal coseno con período aproximado de 6.2832 E-6 seg.

A continuación se presenta la señal de salida V(7), que como puede observarse se encuentra desfasada 180º con respecto a la entrada.

Análisis en el dominio del tiempo

Ahora describiremos algunas sentencias o comandos que se utilizan en PSpice para

observar el comportamiento de circuitos en el dominio del tiempo, es decir realizar el análisis transitorio.

Iniciaremos por describir las sentencias de datos necesarias para la declaración de inductores y condensadores, las cuales son muy similares a las utilizadas para la declaración de elementos resistivos.

3.1 Inductores: Para la declaración de inductores en un circuito se necesitan como mínimo tres campos, aunque en caso de que las condiciones iniciales del elemento sean distintas de cero (0), se hace necesario un campo adicional.

La sintaxis completa de la sentencia de introducción de inductores es la siguiente:

La corriente inicial en el inductor se define como positiva si fluye de N+ hacia N-.

3.2 Condensadores: En el caso de los condensadores la sintaxis es prácticamente igual a la de los inductores con la excepción de que la letra inicial es C.

3.3 Sentencia .TRAN: La sentencia de control .TRAN indica a PSpice que realice el análisis del circuito en el dominio del tiempo, por lo cual debe aparecer obligatoriamente en el fichero fuente de cualquier circuito que se desee analizar en el dominio del tiempo. La misma consta de seis campos, donde los tres últimos son opcionales. Su sintaxis completa es la siguiente :

.TRAN TSTEP TSTOP TSTART TMAX UIC

Donde TSTEP indica es el incremento entre cada valor generado por los comandos .PRINT o .PLOT. TSTOP indica el tiempo total que dura el análisis, TSTART indica el punto de inicio del análisis, el cual por defecto es cero, TMAX es el intervalo de tiempo máximo entre cada valor generado en el análisis realizado por PSpice, si no se especifica el programa lo toma como el tiempo total de análisis dividido por 50, es decir

TMAX = ((TSTOP – TSTART) / 50). El seleccionar un valor de TMAX relativamente pequeño mejora la resolución de los gráficos en el visualizador PROBE, pero hay que tener presente que un valor muy pequeño puede hacer que el análisis tarde considerablemente, en especial si el tiempo total de análisis es un poco prolongado.

Por último el campo UIC indica a PSpice que utilice las condiciones iniciales de corriente y tensión especificadas para los inductores y condensadores que formen parte del circuito.

3.4 Sentencias .PLOT y .PRINT: La sentencia .PLOT nos permite realizar gráficos en función del tiempo de cualquiera de las cantidades obtenidas en el análisis transitorio. La sintaxis de este comando es la siguiente:

.PLOT TRAN VARIABLE 1 ……… >

En el segundo campo (tipo de análisis) se coloca TRAN para indicar análisis transitorio, la sentencia .PLOT nos permite realizar ocho gráficas de manera simultánea, con la opción de indicar los valores mínimos y máximos para cada una.

En el análisis transitorio también se puede utilizar la sentencia .PRINT, la cual tiene una sintaxis similar a la vista en análisis estacionario (2.3), con el único cambio que en el segundo campo (tipo de análisis) se debe colocar TRAN, para indicar análisis transitorio.

3.5 Sentencia .PROBE: La sentencia .PROBE, indica a PSpice que genere un archivo de datos (*.DAT), el cual contiene los resultados del análisis realizado, los cuales pueden ser visualizados gráficamente utilizando el trazador de gráficos Probe que se incluye con el PSpice. Se le puede indicar a PSpice las cantidades que se deseen analizar gráficamente con la ayuda de Probe; si no se indica algún argumento a la sentencia .PROBE PSpice incluye en el fichero todas las cantidades (corriente y tensiones) que intervienen en el circuito.

3. 6 Generador exponenciales: PSpice provee generadores de tensión y

corriente que dependen del tiempo. Con los cuales se pueden generar pulsos cuadrados o exponenciales tal como el que se muestra en la siguiente figura:

La forma general de un pulso generado por PSpice es la siguiente:

En este tipo de generadores, el parámetro V1 especifica el valor inicial de tensión,

V2 indica el valor máximo del pulso, TD1 es el tiempo que tarda en iniciar la subida del pulso, TD2 es el tiempo que tarda en iniciar la caída del pulso (1 es la constante de tiempo en la subida y (2 es la constante de tiempo a la caída del pulso.

La sintaxis para la introducción de este tipo de generadores es la siguiente:

Por ejemplo para introducir un escalón con duración de tres segundos la sintaxis es la siguiente:

V1 1 0 exp(0 1 0 1e-6 3 1e-6), es importante colocar las constantes de tiempo con valores pequeños, para la transición entre los niveles de voltaje sea lo más rápida posible.

3. 7 Generador de lineal por tramos: además del generador de pulsos exponenciales PSpice incluye un generador lineal por tramos o PWL (Piece wise linear). Este generador permite introducir formas de ondas arbitrarias, aproximables por tramos rectilíneos. Para esto basta indicar sucesivamente las coordenadas de tiempo y amplitud en cada uno de los vértices de la señal.

La sintaxis de esta sentencia es la siguiente:

Por ejemplo para generar una señal como la que aparece en la figura, sería necesario la siguiente sentencia:

v1 1 0 pwl(0,1,0.25,1,.5,-1,.9,2.5,1.3,2.5,1.5,1,2,1,2.5,0)

Ejemplo 5:

En el siguiente circuito hallar l a tensión en R2, para t= 5 y 20 mseg, suponiendo que C1 se encuentra inicialmente descargado y que V1 es un pulso de 1 voltio de amplitud y duración de 0.01 segundos. Respuesta: Vo (t=5ms)= -39 V; Vo (t=20ms)= -23.02V.

Para generar el pulso de entrada, se puede utilizar el generador lineal por tramos (PWL), o el generador exponencial. En nuestro caso emplearemos el generador exponencial, para ilustrar su utilización.

El fichero fuente del circuito es el siguiente:

R1 1 2 100

R2 3 0 100

C1 2 3 1u IC=0

*Generador exponencial (V1 V2 td1 tr td2 tf)

V1 1 0 EXP 0 1 0 .0001 .01 .0001

F1 3 2 VS_F1 .99

*Amperímetro

VS_F1 2 0 0

.TRAN .001 .04 0 1e-6 UIC

.PROBE

.END

En las siguientes gráficas se presentan los resultados obtenidos, mediante la simulación.

Pulso de entrada

Tensión de salida

Ejemplo 6:

En el siguiente circuito hallar la tensión en Vo para t > 0, sí V1 = 30 V y

V2 = sen (2x103t).

Respuesta:

El fichero fuente de este circuito es el siguiente:

R1 1 2 1k

R2 2 3 1k

R3 3 0 1k

V1 1 0 DC 30

C1 3 0 1u IC=10

V2 2 0 SIN (0 1 318.309886 0 0 0)

** Analysis setup **

.TRAN .001 .05 0 1E-6 UIC

.PROBE

.END

La curva visualizada en PROBE, se observa en la siguiente figura. Como se puede ver satisface la respuesta obtenida analíticamente.

Ejemplo 7:

En el siguiente circuito, encuentre I1 e I2 para t > 0.

Al desarrollar el circuito de manera analítica, nos encontramos que la corriente inicial I1 (0-)= 6.66667, este es el valor de corriente que se utilizara como condición inicial en el fichero fuente.

La solución analítica de este circuito es la siguiente:

El fichero fuente para la descripción del circuito es el siguiente:

Análisis en el dominio del tiempo

R1 1 2 5

R2 2 3 10

R3 3 0 10

V1 1 0 DC 100

L1 3 0 2 IC=6.6666

.TRAN 20m 1 0 20m UIC

.PROBE

.END

Los resultados obtenidos con PROBE se reflejan en la siguiente gráfica, en la cual se pueden comparar los resultados obtenidos, con la solución analítica.

Análisis en Régimen Permanente Sinusoidal

En el análisis de Régimen Permanente Sinusoidal (RPS) todas las tensiones y corrientes son sinusoides con la misma frecuencia que la excitación, por lo cual el análisis se reduce a determinar el fasor asociado a cada una de las sinusoides. Para hacer esto analíticamente es necesario transformar el circuito a manera fasorial, pero mediante PSpice únicamente hay que indicar al programa que despliegue los resultados en forma de fasores,

ya sea en magnitud y fase o en parte real y parte imaginaria.

• Generadores AC

Para la declaración de los generadores de tensión y corriente en análisis AC, se utilizan las siguientes sintaxis:

Vxxx N+ N- AC AMP DESFASE

Ixxx N+ N- AC AMP DESFASE

Es importante tener en cuenta que el desfase se expresa en grados y con respecto a una señal seno o coseno, la cual elegimos arbitrariamente, con el cuidado de expresar todos los generadores del circuito con respecto al mismo tipo de señal (seno o coseno).

• Sentencia .AC

Esta sentencia es equivalente a la sentencia .DC vista anteriormente, la misma nos

permite realizar un análisis de barrido AC en el dominio de la frecuencia. En nuestro caso nos ocuparemos, por el momento, del análisis en una sola frecuancia.

La sentencia .AC tiene el siguiente formato:

.AC TIPO NP FINICIO FFINAL

En donde el campo TIPO se refiere al tipo de barrido que se va a realizar (lineal, octavas, décadas), en nuestro caso utilizaremos únicamente barrido lineal (LIN). El campo NP indica el número de frecuencias que se analizarán, en nuestro caso siempre será uno; y los campos restantes indican las frecuencias de inicio y fin del barrido, en nuestro caso ambas serán iguales a la frecuencia de la excitación.

4.3 Sentencia .PRINT

La sentencia .PRINT tiene la misma sintaxis, que hemos visto anteriormente, pero para el análisis RPS podemos indicar en la sentencia el tipo de respuesta fasorial que deseamos obtener.

por ejemplo : Se desea obtener la magnitud y fase de una tensión (nodo 3), y las partes real e imaginaria de una corriente (R3) en determinado circuito.

.PRINT AC Vm(3) Vp(3) Ir(r3) I1(r3)

Ejemplo 8:

En el circuito de la figura 1 encontrar el equivalente de Thevenin a la izquierda de las terminales A y B, y utilice el resultado obtenido para calcular el fasor asociado a la tensión V3 en el circuito de la figura 2.

Para obtener el circuito equivalente de Thevenin utilizaremos la sentencia .TF para encontrar la impedancia vista desde las terminales A y B , y mediante el análisis AC y la sentencia .PRINT encontraremos la magnitud y la fase de la tensión entre dichas terminales.

Para la primera parte de la simulación utilizaremos el siguiente fichero

EJEMPLO 8 PARTE 1

R1 1 3 100

R2 4 0 7k

R3 2 0 8k

V1 1 2 AC 4 45

I1 3 1 AC .1 45

F1 3 2 VF_F1 9

VF_F1 3 4 0

.TF V(2) V1

.AC LIN 1 159.2 159.2

.PRINT AC Vm(2) Vp(2) Vr(2) Vi(2)

.END

En el fichero de salida encontraremos que la resistencia de Thevenin es 4 K(, mientras que la tensión de salida, es 2.121 + 2.121 j, es decir magnitud 3 y fase 45º.

Para la segunda parte del ejemplo, el circuito es el siguiente

Para encontrar el fasor relacionado a la tensión en el nodo 3, es necesario utilizar la sentencia .PRINT e indicar al software que encuentre la magnitud y fase en el este nodo.

Hay que tener en cuenta que se utiliza el modelo del Amplificador operacional ideal.

El fichero fuente es el siguiente

EJEMPLO 8 PARTE 2

RTH 1 2 4k

RB 4 3 1k

RA 2 0 4k

V4 1 0 AC 3V 45

CB 2 4 500n

CA 2 3 1u

**AMPLIFICADOR OPERACIONAL

RIN 4 0 1E10

E1 3 0 0 4 1E6

.AC LIN 1 159.15 159.15

.PRINT AC Vm(3) Vp(3) Vr(3) Vi(3)

.END

En el fichero de salida se podrá observar que la magnitud de la tensión es 0.25 V y la fase es -135º.

Ejemplo 9:

En el circuito de la figura observar como cambia la amplitud y la fase de la tensión de salida en relación con los cambios de la frecuencia del generador V1.

Para realizar este ejemplo, utilizando el comando .AC en análisis de una sola frecuencia, es necesario efectuar la simulación de manera individual, para cada una de las frecuencias deseadas. En el fichero fuente únicamente se cambia el valor de frecuencia en la sentencia .AC y indica a PSpice, mediante la sentencia .PRINT que calcule la magnitud y fase en el nodo de salida.

El fichero fuente es el siguiente.

EJEMPLO 9

V1 1 0 DC 0V AC 10 0

R1 1 2 1k

R2 4 3 1k

F1 0 2 VF_F1 10

C1 3 0 10n

L1 2 SALIDA 100m

*AMPERÍMETRO

VF_F1 SALIDA 3 0V

*AMPLIFICADOR

R3 2 4 1T

E1 SALIDA 0 2 4 1E8

*CAMBIOS DE FRECUENCIA

.AC LIN 1 100 100

.PRINT AC VM(5) VP(5)

.END

Los resultados obtenidos para este análisis son los siguientes :

Estos resultados se podrían obtener en una sola simulación, mediante las sentencias . AC, realizando un barrido de frecuencias desde 100 hasta 100k y luego visualizando las variaciones de magnitud y fase mediante la sentencia .PROBE.

Lo s únicos cambios que habría que efectuar en el fichero fuente seria, modificar la sentencia .AC, de la siguiente manera:

.AC LIN 600 100 100k

Se puede escoger un valor mayor a 600 para obtener mayor cantidad de puntos en la gráfica. Y se debe añadir la sentencia .PROBE V(5) V(5)

Los resultados de magnitud y fase se observan en la siguiente gráfica

Referencias bibliográficas

• 1. NILSSON, J,W.; RIEDEL, S.A.

"Introduction to PSpice", Wilimington, D.: Addison-Wesley Iberoamericana, S.A., 1994.

• 2. ALVIN CONNELY, J.; PYUNG CHOI

"Macromodeling with PSpice", Englewood Cliffs, N.J.: Prentice-Hall, 1992.

• 3. RASHID, M.H.

"SPICE for circuits and Electronic Using PSpice", Englewoodc Cliffs, N.J.: Prentice-hall, 1990.

Enviado por:

Pablo Turmero